components_music_AudioPlayerView.bs

import "pkg:/source/api/baserequest.bs"
import "pkg:/source/api/Image.bs"
import "pkg:/source/roku_modules/log/LogMixin.brs"
import "pkg:/source/utils/config.bs"
import "pkg:/source/utils/misc.bs"

sub init()
  m.log = log.Logger("AudioPlayerView")

  m.top.optionsAvailable = false
  m.inScrubMode = false
  m.lastRecordedPositionTimestamp = 0
  m.scrubTimestamp = -1
  m.currentBackdropUrl = ""

  m.queueManager = m.global.queueManager
  m.playlistTypeCount = m.queueManager.callFunc("getQueueUniqueTypes").count()

  m.audioPlayer = m.global.audioPlayer
  m.audioPlayer.observeField("state", "audioStateChanged")
  m.audioPlayer.observeField("position", "audioPositionChanged")
  m.audioPlayer.observeField("bufferingStatus", "bufferPositionChanged")

  setupAnimationTasks()
  setupButtons()
  setupInfoNodes()
  setupDataTasks()
  setupScreenSaver()
  applyTheme()

  m.seekPosition.translation = [720 - (m.seekPosition.width / 2), m.seekPosition.translation[1]]

  m.screenSaverTimeout = 300

  m.LoadScreenSaverTimeoutTask.observeField("content", "onScreensaverTimeoutLoaded")
  m.LoadScreenSaverTimeoutTask.control = "RUN"

  m.di = CreateObject("roDeviceInfo")

  ' Write screen tracker for screensaver
  WriteAsciiFile("tmp:/scene.temp", "nowplaying")
  MoveFile("tmp:/scene.temp", "tmp:/scene")

  loadButtons()
  pageContentChanged()
  setShuffleIconState()
  setLoopButtonImage()
  ' Set lastFocus for JRScreen lifecycle management
  m.top.lastFocus = m.buttons
end sub

sub applyTheme()
  constants = m.global.constants

  m.seekBar.color = constants.colorBlack + constants.alpha60
  m.bufferPosition.color = constants.colorBackgroundSecondary
  m.playPosition.color = constants.colorSecondary
  m.thumb.blendColor = constants.colorPrimary
end sub

sub onScreensaverTimeoutLoaded()
  data = m.LoadScreenSaverTimeoutTask.content
  m.LoadScreenSaverTimeoutTask.unobserveField("content")
  if isValid(data)
    m.screenSaverTimeout = data
  end if
end sub

sub setupScreenSaver()
  m.screenSaverBackground = m.top.FindNode("screenSaverBackground")

  ' Album Art Screensaver
  m.screenSaverAlbumCover = m.top.FindNode("screenSaverAlbumCover")
  m.screenSaverAlbumAnimation = m.top.findNode("screenSaverAlbumAnimation")
  m.screenSaverAlbumCoverFadeIn = m.top.findNode("screenSaverAlbumCoverFadeIn")

  ' Audio Screensaver
  m.PosterOne = m.top.findNode("PosterOne")
  m.PosterOne.uri = "pkg:/images/branding/logo.png"
  m.BounceAnimation = m.top.findNode("BounceAnimation")
  m.PosterOneFadeIn = m.top.findNode("PosterOneFadeIn")
end sub

sub setupAnimationTasks()
  m.playPositionAnimation = m.top.FindNode("playPositionAnimation")
  m.playPositionAnimationWidth = m.top.FindNode("playPositionAnimationWidth")

  m.bufferPositionAnimation = m.top.FindNode("bufferPositionAnimation")
  m.bufferPositionAnimationWidth = m.top.FindNode("bufferPositionAnimationWidth")
end sub

' Creates tasks to gather data needed to render Scene and play song
sub setupDataTasks()
  ' Load meta data
  m.LoadMetaDataTask = CreateObject("roSGNode", "LoadItemsTask")
  m.LoadMetaDataTask.itemsToLoad = "metaData"

  ' Load audio stream
  m.LoadAudioStreamTask = CreateObject("roSGNode", "LoadItemsTask")
  m.LoadAudioStreamTask.itemsToLoad = "audioStream"

  m.LoadScreenSaverTimeoutTask = CreateObject("roSGNode", "LoadScreenSaverTimeoutTask")
end sub

' Setup playback buttons, default to Play button selected
sub setupButtons()
  m.buttons = m.top.findNode("buttons")

  ' Get button references for later use
  m.playButton = m.buttons.findNode("play")
  m.shuffleButton = m.buttons.findNode("shuffle")
  m.repeatButton = m.buttons.findNode("repeat")

  ' If we're playing a mixed playlist, remove the shuffle and repeat buttons
  if m.playlistTypeCount > 1
    if isValid(m.shuffleButton)
      m.buttons.removeChild(m.shuffleButton)
      m.shuffleButton = invalid
    end if

    if isValid(m.repeatButton)
      m.buttons.removeChild(m.repeatButton)
      m.repeatButton = invalid
    end if
  end if

  ' Set default focus to play button (index 1)
  m.buttons.buttonFocused = 1

  ' Center button group horizontally
  m.buttons.callFunc("center")

  ' Observe button selection
  m.buttons.observeField("buttonSelected", "onButtonSelected")
end sub

' Event handler when user selects a button via OK key
sub onButtonSelected()
  buttonIndex = m.buttons.buttonSelected
  button = m.buttons.getChild(buttonIndex)

  if not isValid(button) then return

  if button.id = "play"
    playAction()
  else if button.id = "previous"
    previousClicked()
  else if button.id = "next"
    nextClicked()
  else if button.id = "shuffle"
    shuffleClicked()
  else if button.id = "repeat"
    loopClicked()
  end if
end sub

sub setupInfoNodes()
  m.albumCover = m.top.findNode("albumCover")
  m.playPosition = m.top.findNode("playPosition")
  m.bufferPosition = m.top.findNode("bufferPosition")
  m.seekBar = m.top.findNode("seekBar")
  m.thumb = m.top.findNode("thumb")
  m.positionTimestamp = m.top.findNode("positionTimestamp")
  m.seekPosition = m.top.findNode("seekPosition")
  m.seekTimestamp = m.top.findNode("seekTimestamp")
  m.totalLengthTimestamp = m.top.findNode("totalLengthTimestamp")
end sub

sub bufferPositionChanged()
  if m.inScrubMode then return

  if not isValid(m.audioPlayer.bufferingStatus)
    bufferPositionBarWidth = m.seekBar.width
  else
    bufferPositionBarWidth = m.seekBar.width * m.audioPlayer.bufferingStatus.percentage
  end if

  ' Ensure position bar is never wider than the seek bar
  if bufferPositionBarWidth > m.seekBar.width
    bufferPositionBarWidth = m.seekBar.width
  end if

  ' Use animation to make the display smooth
  m.bufferPositionAnimationWidth.keyValue = [m.bufferPosition.width, bufferPositionBarWidth]
  m.bufferPositionAnimation.control = "start"
end sub

sub audioPositionChanged()
  stopLoadingSpinner()

  if m.audioPlayer.position = 0
    m.playPosition.width = 0
  end if

  if not isValid(m.audioPlayer.position)
    playPositionBarWidth = 0
  else if not isValid(m.songDuration)
    playPositionBarWidth = 0
  else
    songPercentComplete = m.audioPlayer.position / m.songDuration
    playPositionBarWidth = m.seekBar.width * songPercentComplete
  end if

  ' Ensure position bar is never wider than the seek bar
  if playPositionBarWidth > m.seekBar.width
    playPositionBarWidth = m.seekBar.width
  end if

  if not m.inScrubMode
    moveSeekbarThumb(playPositionBarWidth)
    ' Change the seek position timestamp
    m.seekTimestamp.text = secondsToTimestamp(m.audioPlayer.position, false)
  end if

  ' Use animation to make the display smooth
  m.playPositionAnimationWidth.keyValue = [m.playPosition.width, playPositionBarWidth]
  m.playPositionAnimation.control = "start"

  ' Update displayed position timestamp
  if isValid(m.audioPlayer.position)
    m.lastRecordedPositionTimestamp = m.audioPlayer.position
    m.positionTimestamp.text = secondsToTimestamp(m.audioPlayer.position, false)
  else
    m.lastRecordedPositionTimestamp = 0
    m.positionTimestamp.text = "0:00"
  end if

  ' Only fall into screensaver logic if the user has screensaver enabled in Roku settings
  if m.screenSaverTimeout > 0
    if m.di.TimeSinceLastKeypress() >= m.screenSaverTimeout - 2
      if not screenSaverActive()
        startScreenSaver()
      end if
    end if
  end if
end sub

function screenSaverActive() as boolean
  return m.screenSaverBackground.visible or m.screenSaverAlbumCover.opacity > 0 or m.PosterOne.opacity > 0
end function

sub startScreenSaver()
  m.screenSaverBackground.visible = true
  m.top.overhangVisible = false

  if m.albumCover.uri = ""
    ' Audio Logo Screensaver
    m.PosterOne.visible = true
    m.PosterOneFadeIn.control = "start"
    m.BounceAnimation.control = "start"
  else
    ' Album Art Screensaver
    m.screenSaverAlbumCoverFadeIn.control = "start"
    m.screenSaverAlbumAnimation.control = "start"
  end if
end sub

sub endScreenSaver()
  m.PosterOneFadeIn.control = "pause"
  m.screenSaverAlbumCoverFadeIn.control = "pause"
  m.screenSaverAlbumAnimation.control = "pause"
  m.BounceAnimation.control = "pause"
  m.screenSaverBackground.visible = false
  m.screenSaverAlbumCover.opacity = 0
  m.PosterOne.opacity = 0
  m.top.overhangVisible = true
end sub

sub audioStateChanged()
  ' Update play/pause button icon based on audio state
  if isValid(m.playButton)
    if m.audioPlayer.state = "playing"
      m.playButton.icon = "pkg:/images/icons/pause.png"
    else
      m.playButton.icon = "pkg:/images/icons/play.png"
    end if
  end if

  ' Song Finished, attempt to move to next song
  if m.audioPlayer.state = "finished"
    ' User has enabled single song loop, play current song again
    if m.audioPlayer.loopMode = "one"
      m.scrubTimestamp = -1
      playAction()
      exitScrubMode()
      return
    end if

    if m.queueManager.callFunc("getPosition") < m.queueManager.callFunc("getCount") - 1
      m.top.state = "finished"
    else
      ' We are at the end of the song queue

      ' User has enabled loop for entire song queue, move back to first song
      if m.audioPlayer.loopMode = "all"
        m.queueManager.callFunc("setPosition", -1)
        LoadNextSong()
        return
      end if

      ' Return to previous screen
      m.top.state = "finished"
    end if
  end if
end sub

function playAction() as boolean

  if m.audioPlayer.state = "playing"
    m.audioPlayer.control = "pause"
    if isValid(m.playButton)
      m.playButton.icon = "pkg:/images/icons/play.png"
    end if
    ' Allow screen to go to real screensaver
    WriteAsciiFile("tmp:/scene.temp", "nowplaying-paused")
    MoveFile("tmp:/scene.temp", "tmp:/scene")
  else if m.audioPlayer.state = "paused"
    m.audioPlayer.control = "resume"
    if isValid(m.playButton)
      m.playButton.icon = "pkg:/images/icons/pause.png"
    end if
    ' Write screen tracker for screensaver
    WriteAsciiFile("tmp:/scene.temp", "nowplaying")
    MoveFile("tmp:/scene.temp", "tmp:/scene")
  else if m.audioPlayer.state = "finished"
    m.audioPlayer.control = "play"
    if isValid(m.playButton)
      m.playButton.icon = "pkg:/images/icons/pause.png"
    end if
    ' Write screen tracker for screensaver
    WriteAsciiFile("tmp:/scene.temp", "nowplaying")
    MoveFile("tmp:/scene.temp", "tmp:/scene")
  end if

  return true
end function

function previousClicked() as boolean
  currentQueuePosition = m.queueManager.callFunc("getPosition")
  if currentQueuePosition = 0 then return false

  if m.playlistTypeCount > 1
    previousItem = m.queueManager.callFunc("getItemByIndex", currentQueuePosition - 1)
    previousItemType = m.queueManager.callFunc("getItemType", previousItem)

    if previousItemType <> "audio"
      m.audioPlayer.control = "stop"

      m.global.sceneManager.callFunc("clearPreviousScene")
      m.queueManager.callFunc("moveBack")
      m.queueManager.callFunc("playQueue")
      return true
    end if
  end if

  exitScrubMode()

  m.lastRecordedPositionTimestamp = 0
  m.positionTimestamp.text = "0:00"

  if m.audioPlayer.state = "playing"
    m.audioPlayer.control = "stop"
  end if

  ' Reset loop mode due to manual user interaction
  if m.audioPlayer.loopMode = "one"
    resetLoopModeToDefault()
  end if

  m.queueManager.callFunc("moveBack")
  pageContentChanged()

  return true
end function

sub resetLoopModeToDefault()
  m.audioPlayer.loopMode = ""
  setLoopButtonImage()
end sub

function loopClicked() as boolean
  if m.audioPlayer.loopMode = ""
    m.audioPlayer.loopMode = "all"
  else if m.audioPlayer.loopMode = "all"
    m.audioPlayer.loopMode = "one"
  else
    m.audioPlayer.loopMode = ""
  end if

  setLoopButtonImage()

  return true
end function

sub setLoopButtonImage()
  if not isValid(m.repeatButton) then return

  if m.audioPlayer.loopMode = "all"
    ' Repeat all - use repeat.png with active state
    m.repeatButton.icon = "pkg:/images/icons/repeat.png"
    m.repeatButton.selected = true
  else if m.audioPlayer.loopMode = "one"
    ' Repeat one - use repeat-1.png with active state
    m.repeatButton.icon = "pkg:/images/icons/repeat-1.png"
    m.repeatButton.selected = true
  else
    ' Repeat off - use repeat.png without active state
    m.repeatButton.icon = "pkg:/images/icons/repeat.png"
    m.repeatButton.selected = false
  end if
end sub

function nextClicked() as boolean

  if m.playlistTypeCount > 1
    currentQueuePosition = m.queueManager.callFunc("getPosition")
    if currentQueuePosition < m.queueManager.callFunc("getCount") - 1

      nextItem = m.queueManager.callFunc("getItemByIndex", currentQueuePosition + 1)
      nextItemType = m.queueManager.callFunc("getItemType", nextItem)

      if nextItemType <> "audio"
        m.audioPlayer.control = "stop"

        m.global.sceneManager.callFunc("clearPreviousScene")
        m.queueManager.callFunc("moveForward")
        m.queueManager.callFunc("playQueue")
        return true
      end if
    end if
  end if

  exitScrubMode()

  m.lastRecordedPositionTimestamp = 0
  m.positionTimestamp.text = "0:00"

  ' Reset loop mode due to manual user interaction
  if m.audioPlayer.loopMode = "one"
    resetLoopModeToDefault()
  end if

  if m.queueManager.callFunc("getPosition") < m.queueManager.callFunc("getCount") - 1
    LoadNextSong()
  end if

  return true
end function

sub toggleShuffleEnabled()
  m.queueManager.callFunc("toggleShuffle")
end sub

function findCurrentSongIndex(songList) as integer
  if not isValidAndNotEmpty(songList) then return 0

  for i = 0 to songList.count() - 1
    if songList[i].id = m.queueManager.callFunc("getCurrentItem").id
      return i
    end if
  end for

  return 0
end function

function shuffleClicked() as boolean
  currentSongIndex = findCurrentSongIndex(m.queueManager.callFunc("getUnshuffledQueue"))

  toggleShuffleEnabled()

  if not m.queueManager.callFunc("getIsShuffled")
    ' Shuffle off
    if isValid(m.shuffleButton)
      m.shuffleButton.selected = false
    end if
    m.queueManager.callFunc("setPosition", currentSongIndex)
    setTrackNumberDisplay()
    return true
  end if

  ' Shuffle on
  if isValid(m.shuffleButton)
    m.shuffleButton.selected = true
  end if
  setTrackNumberDisplay()

  return true
end function

sub setShuffleIconState()
  if not isValid(m.shuffleButton) then return

  if m.queueManager.callFunc("getIsShuffled")
    m.shuffleButton.selected = true
  else
    m.shuffleButton.selected = false
  end if
end sub

sub setTrackNumberDisplay()
  setFieldTextValue("numberofsongs", tr("Track") + " " + tr("%1 of %2").Replace("%1", stri(m.queueManager.callFunc("getPosition") + 1).trim()).Replace("%2", stri(m.queueManager.callFunc("getCount")).trim()))
end sub

sub LoadNextSong()
  if m.audioPlayer.state = "playing"
    m.audioPlayer.control = "stop"
  end if

  exitScrubMode()

  ' Reset playPosition bar without animation
  m.playPosition.width = 0
  m.queueManager.callFunc("moveForward")
  pageContentChanged()
end sub

' Update values on screen when page content changes
sub pageContentChanged()

  m.LoadAudioStreamTask.control = "STOP"

  currentItem = m.queueManager.callFunc("getCurrentItem")

  m.LoadAudioStreamTask.itemId = currentItem.id
  m.LoadAudioStreamTask.observeField("content", "onAudioStreamLoaded")
  m.LoadAudioStreamTask.control = "RUN"
end sub

' If we have more than 1 song to play, set initial button states
sub loadButtons()
  if m.queueManager.callFunc("getCount") > 1
    ' Set initial loop/repeat button state
    setLoopButtonImage()
  end if
end sub

sub onAudioStreamLoaded()
  stopLoadingSpinner()
  data = m.LoadAudioStreamTask.content[0]
  m.LoadAudioStreamTask.unobserveField("content")
  if isValid(data) and data.count() > 0
    ' Reset buffer bar without animation
    m.bufferPosition.width = 0

    useMetaTask = false
    currentItem = m.queueManager.callFunc("getCurrentItem")

    if not isValid(currentItem.RunTimeTicks)
      useMetaTask = true
    end if

    if not isValid(currentItem.AlbumArtist)
      useMetaTask = true
    end if

    if not isValid(currentItem.name)
      useMetaTask = true
    end if

    if not isValid(currentItem.Artists)
      useMetaTask = true
    end if

    ' Set backdrop immediately from available data (will be set once in onMetaDataLoaded if useMetaTask = true)
    if not useMetaTask
      ' We have all data, set backdrop now from parent backdrop
      if isValid(currentItem.ParentBackdropItemId) and isValid(currentItem.ParentBackdropImageTags) and currentItem.ParentBackdropImageTags.count() > 0
        localDevice = m.global.device
        backdropUri = ImageURL(currentItem.ParentBackdropItemId, "Backdrop", { "maxHeight": localDevice.uiResolution[1], "maxWidth": localDevice.uiResolution[0], "tag": currentItem.ParentBackdropImageTags[0] })
        m.log.info("Backdrop change (immediate): old=", m.currentBackdropUrl, "new=", backdropUri)
        m.currentBackdropUrl = backdropUri
        m.global.sceneManager.callFunc("setBackgroundImage", backdropUri)
      else
        m.log.info("Backdrop change (immediate): old=", m.currentBackdropUrl, "new=(empty)")
        m.currentBackdropUrl = ""
        m.global.sceneManager.callFunc("setBackgroundImage", "")
      end if
    end if

    ' If we don't have enough data to populate the screen, load metadata (which will also set backdrop)
    if useMetaTask
      m.LoadMetaDataTask.itemId = currentItem.id
      m.LoadMetaDataTask.observeField("content", "onMetaDataLoaded")
      m.LoadMetaDataTask.control = "RUN"
    else

      ' poster image
      if isValid(currentItem.AlbumId) and isValid(currentItem.AlbumPrimaryImageTag) and currentItem.AlbumPrimaryImageTag <> ""
        ' use primary album image
        setPosterImage(ImageURL(currentItem.AlbumId, "Primary", { "maxHeight": 500, "maxWidth": 500, "tag": currentItem.AlbumPrimaryImageTag }))
      else if isValid(currentItem.ImageTags) and currentItem.ImageTags["Primary"] <> invalid
        ' use primary poster image
        setPosterImage(ImageURL(currentItem.id, "Primary", { "maxHeight": 500, "maxWidth": 500, "tag": currentItem.ImageTags["Primary"] }))
      else
        ' no poster available, show placeholder image
        setPosterImage("pkg:/images/icons/album.png")
      end if

      setScreenTitle(currentItem)
      setOnScreenTextValues(currentItem)
      m.songDuration = currentItem.RunTimeTicks / 10000000.0

      ' Update displayed total audio length
      m.totalLengthTimestamp.text = ticksToHuman(currentItem.RunTimeTicks)
    end if

    m.audioPlayer.content = data
    m.audioPlayer.control = "none"
    m.audioPlayer.control = "play"
  end if
end sub

sub onMetaDataLoaded()
  data = m.LoadMetaDataTask.content[0]
  m.LoadMetaDataTask.unobserveField("content")
  if isValid(data) and data.count() > 0 and isValid(data.json)
    ' Set backdrop with fallback strategy: artist backdrop → parent backdrop → clear
    backdropSet = false
    localDevice = m.global.device

    ' Try artist backdrop first (preferred)
    if isValid(data.json.ArtistItems) and isValid(data.json.ArtistItems[0]) and isValid(data.json.ArtistItems[0].id)
      artist = data.json.ArtistItems[0]
      if isValid(artist.BackdropImageTags) and artist.BackdropImageTags.count() > 0
        backdropUri = ImageURL(artist.id, "Backdrop", { "maxHeight": localDevice.uiResolution[1], "maxWidth": localDevice.uiResolution[0], "tag": artist.BackdropImageTags[0] })
        m.log.info("Backdrop change (artist): old=", m.currentBackdropUrl, "new=", backdropUri)
        m.currentBackdropUrl = backdropUri
        m.global.sceneManager.callFunc("setBackgroundImage", backdropUri)
        backdropSet = true
      end if
    end if

    ' Fall back to parent backdrop if no artist backdrop
    if not backdropSet
      if isValid(data.json.ParentBackdropItemId) and isValid(data.json.ParentBackdropImageTags) and data.json.ParentBackdropImageTags.count() > 0
        backdropUri = ImageURL(data.json.ParentBackdropItemId, "Backdrop", { "maxHeight": localDevice.uiResolution[1], "maxWidth": localDevice.uiResolution[0], "tag": data.json.ParentBackdropImageTags[0] })
        m.log.info("Backdrop change (parent): old=", m.currentBackdropUrl, "new=", backdropUri)
        m.currentBackdropUrl = backdropUri
        m.global.sceneManager.callFunc("setBackgroundImage", backdropUri)
        backdropSet = true
      end if
    end if

    ' Clear backdrop if no valid source found
    if not backdropSet
      m.log.info("Backdrop change (clear): old=", m.currentBackdropUrl, "new=(empty)")
      m.currentBackdropUrl = ""
      m.global.sceneManager.callFunc("setBackgroundImage", "")
    end if

    setPosterImage(data.posterURL)
    setScreenTitle(data.json)
    setOnScreenTextValues(data.json)

    if isValid(data.json.RunTimeTicks)
      m.songDuration = data.json.RunTimeTicks / 10000000.0

      ' Update displayed total audio length
      m.totalLengthTimestamp.text = ticksToHuman(data.json.RunTimeTicks)
    end if
  end if
end sub

' Set poster image on screen
sub setPosterImage(posterURL)
  if isValid(posterURL)
    if m.albumCover.uri <> posterURL
      if posterURL = "pkg:/images/icons/album.png"
        constants = m.global.constants
        ' color the white album placeholder to match theme
        m.albumCover.blendColor = constants.colorTextSecondary
        m.screenSaverAlbumCover.blendColor = constants.colorTextSecondary
      else
        ' reset blend color to default white
        m.albumCover.blendColor = "0xFFFFFFFF"
        m.screenSaverAlbumCover.blendColor = "0xFFFFFFFF"
      end if

      m.albumCover.uri = posterURL
      m.screenSaverAlbumCover.uri = posterURL
    end if
  end if
end sub

' Set screen's title text
sub setScreenTitle(json)
  newTitle = ""
  if isValid(json)
    if isValid(json.AlbumArtist)
      newTitle = json.AlbumArtist
    end if
    if isValid(json.AlbumArtist) and isValid(json.name)
      newTitle = newTitle + " / "
    end if
    if isValid(json.name)
      newTitle = newTitle + json.name
    end if
  end if

  if m.top.overhangTitle <> newTitle
    m.top.overhangTitle = newTitle
  end if
end sub

' Populate on screen text variables
sub setOnScreenTextValues(json)
  if isValid(json)
    if m.playlistTypeCount = 1
      setTrackNumberDisplay()
    end if

    setFieldTextValue("artist", json.Artists[0])
    setFieldTextValue("song", json.name)
  end if
end sub

' processScrubAction: Handles +/- seeking for the audio trickplay bar
'
' @param {integer} seekStep - seconds to move the trickplay position (negative values allowed)
sub processScrubAction(seekStep as integer)
  ' Prepare starting playStart property value
  if m.scrubTimestamp = -1
    m.scrubTimestamp = m.lastRecordedPositionTimestamp
  end if

  ' Don't let seek to go past the end of the song
  if m.scrubTimestamp + seekStep > m.songDuration - 5
    return
  end if

  if seekStep > 0
    ' Move seek forward
    m.scrubTimestamp += seekStep
  else if m.scrubTimestamp >= Abs(seekStep)
    ' If back seek won't go below 0, move seek back
    m.scrubTimestamp += seekStep
  else
    ' Back seek would go below 0, set to 0 directly
    m.scrubTimestamp = 0
  end if

  ' Move the seedbar thumb forward
  songPercentComplete = m.scrubTimestamp / m.songDuration
  playPositionBarWidth = m.seekBar.width * songPercentComplete

  moveSeekbarThumb(playPositionBarWidth)

  ' Change the displayed position timestamp
  m.seekTimestamp.text = secondsToTimestamp(m.scrubTimestamp, false)
end sub

' resetSeekbarThumb: Resets the thumb to the playing position
'
sub resetSeekbarThumb()
  m.scrubTimestamp = -1
  moveSeekbarThumb(m.playPosition.width)
end sub

' moveSeekbarThumb: Positions the thumb on the seekbar
'
' @param {float} playPositionBarWidth - width of the play position bar
sub moveSeekbarThumb(playPositionBarWidth as float)
  ' Center the thumb on the play position bar
  thumbPostionLeft = playPositionBarWidth - 10

  ' Don't let thumb go below 0
  if thumbPostionLeft < 0 then thumbPostionLeft = 0

  ' Don't let thumb go past end of seekbar
  if thumbPostionLeft > m.seekBar.width - 25
    thumbPostionLeft = m.seekBar.width - 25
  end if

  ' Move the thumb
  m.thumb.translation = [thumbPostionLeft, m.thumb.translation[1]]

  ' Move the seek position element so it follows the thumb
  m.seekPosition.translation = [720 + thumbPostionLeft - (m.seekPosition.width / 2), m.seekPosition.translation[1]]
end sub

' exitScrubMode: Moves player out of scrub mode state,  resets back to standard play mode
'
sub exitScrubMode()
  m.buttons.callFunc("focus")
  m.thumb.setFocus(false)

  if m.seekPosition.visible
    m.seekPosition.visible = false
  end if

  resetSeekbarThumb()

  m.inScrubMode = false
  m.thumb.visible = false
end sub

' Process key press events
function onKeyEvent(key as string, press as boolean) as boolean

  ' Key bindings for remote control buttons
  if press
    ' If user presses key to turn off screensaver, don't do anything else with it
    if screenSaverActive()
      endScreenSaver()
      return true
    end if

    ' Key Event handler when m.thumb is in focus
    if m.thumb.hasFocus()
      if key = "right"
        m.inScrubMode = true
        processScrubAction(10)
        return true
      end if

      if key = "left"
        m.inScrubMode = true
        processScrubAction(-10)
        return true
      end if

      if key = "OK" or key = "play"
        if m.inScrubMode
          startLoadingSpinner()
          m.inScrubMode = false
          m.audioPlayer.seek = m.scrubTimestamp
          return true
        end if

        return playAction()
      end if
    end if

    if key = "play"
      return playAction()
    end if

    if key = "up"
      if not m.thumb.visible
        m.thumb.visible = true
      end if
      if not m.seekPosition.visible
        m.seekPosition.visible = true
      end if

      m.thumb.setFocus(true)
      m.buttons.setFocus(false)
      return true
    end if

    if key = "down"
      if m.thumb.visible
        exitScrubMode()
      end if
      return true
    end if

    if key = "back"
      m.audioPlayer.control = "stop"
      m.audioPlayer.loopMode = ""
    else if key = "rewind"
      return previousClicked()
    else if key = "fastforward"
      return nextClicked()
    end if
  end if

  return false
end function

sub OnScreenHidden()
  ' Write screen tracker for screensaver
  WriteAsciiFile("tmp:/scene.temp", "")
  MoveFile("tmp:/scene.temp", "tmp:/scene")
end sub